Programowanie głośniczka w asemblerze pod Linuksem

Czy nie myślicie czasem, jakby to było, gdyby można było wzbogacić swój program oprócz efektu wizualnego, także o efekt dźwiękowy?

Programowanie kart dźwiękowych (zwłaszcza tych nowoczesnych) może sprawiać niemałe kłopoty. Stary, poczciwy PC-Speaker jest jednak urządzeniem względnie prostym w programowaniu i to właśnie tutaj udowodnię. Najpierw troszkę teorii, potem - do dzieła!

Linux jest systemem działającym w pełni w trybie chronionym. Dlatego bez uprawnień administratora nie możemy bezpośrednio pisać do interesujących nas portów (42h, 43h, 61h).

Na szczęście istnieje funkcja systemowa sys_ioctl (numer 54) i to ona nam pomoże w ożywieniu głośniczka systemowego. Funkcja ta jako parametry przyjmuje:

• EBX = deskryptor otwartego pliku (dla nas będzie to /dev/console lub standardowe wyjście - STDOUT) do zapisu
• ECX = stała KIOCSOUND = 0x4B2F (patrz: /usr/include/linux/kd.h)
• EDX =
  • 0 gdy chcemy wyłączyć dźwięk
  • 1234DDh / częstotliwość, gdy chcemy mieć dźwięk o żądanej częstotliwości

Ale to nie wszystko. Chcemy, by nasz dźwięk chwilę potrwał. W tym celu skorzystamy z funkcji sys_nanosleep (numer 162). Jej składnia jest prosta:

• EBX = adres struktury timespec wyglądającej tak (w składni FASM):

  	struc	timespec
  	 {
  		.tv_sec		rd 1
  		.tv_nsec	rd 1
  	 }

  i zawierającej wpisane ilości sekund i nanosekund, które należy odczekać.
• ECX = adres struktury timespec, do której funkcja zapisze wynik swojego działania.

Jak widać schemat działania naszego programu jest dość prosty:

1. Otworzyć /dev/console do zapisu. W przypadku niepowodzenia użyć STDOUT
2. Ewentualnie wywołać sys_ioctl z EDX=0 w celu wyłączenia aktualnie trwającego dźwięku
3. Tyle razy ile trzeba, wywołać sys_ioctl z odpowiednimi wartościami w EDX i korzystać z funkcji sys_nanosleep
4. Wywołać sys_ioctl z EDX=0 w celu wyłączenia dźwięku
5. Jeśli otworzyliśmy /dev/console, zamknąć ten deskryptor

Przykładowy program wygląda tak (używanie załączników z mojej biblioteki nie jest konieczne - w kodzie mówię, jak i co zamienić):

; Program wytwarzający dźwięki z głośniczka przez sys_ioctl
; Autor: Bogdan D.
; Kontakt: bogdandr (at) op (dot) pl
;
; kompilacja:
;   fasm spkr.asm spkr

format ELF executable
entry _start

segment readable executable

include "bibl/incl/linuxbsd/fasm/fasm_system.inc"

KIOCSOUND	= 0x4B2F

_start:
	mov	eax, sys_open	; sys_open = 5
	mov	ebx, konsola
	mov	ecx, O_WRONLY	; O_WRONLY = 1
	mov	edx, 777o
	int	80h

	cmp	eax, 0		; czy wystąpił błąd (EAX < 0) ?
	jg	.otw_ok

	mov	eax, 1		; jak nie otworzyliśmy konsoli, piszemy
				; na STDOUT (1)
.otw_ok:
	mov	ebx, eax	; EBX = uchwyt do pliku

	mov	eax, sys_ioctl	; sys_ioctl = 54
	mov	ecx, KIOCSOUND
	xor	edx, edx	; wyłączenie ewentualnych dźwięków
	int	80h

	mov	eax, sys_ioctl
	mov	edx, 2711	; 2711 = 1234DDh/440. 440 Hz to dźwięk A
	int	80h

        mov     cx, 0fh
        mov     dx, 4240h	; 0F4240h to 1 milion dziesiętnie
        call    pauza

        mov     eax, sys_ioctl
	mov	ecx, KIOCSOUND
	xor	edx, edx	; wyłączamy dźwięk
	int     80h

	cmp	ebx, 2		; sprawdzamy, czy używamy /dev/console
				; czy STDOUT
	jbe	.koniec

	mov	eax, sys_close	; sys_close = 6
	int	80h		; zamykamy otwarty plik konsoli

.koniec:
	mov	eax, 1
	xor	ebx, ebx
	int	80h

pauza:				;procedura pauzująca przez CX:DX milisekund
	push    ebx
	push    ecx
	push    edx

	mov     ax, cx
	shl     eax, 16
	mov     ebx, 1000000
	mov     ax, dx 			; EAX = CX:DX
	xor     edx, edx
	div     ebx			; CX:DX dzielimy przez milion
	mov     [t1.tv_sec], eax 	; EAX = liczba sekund

	mov     ebx, 1000
	mov     eax, edx		;EAX = pozostała liczba mikrosekund
	mul     ebx
	mov     [t1.tv_nsec], eax 	; EAX = liczba nanosekund

	mov     eax, sys_nanosleep	; funkcja numer 162
	mov     ebx, t1
	mov     ecx, t2
	int     80h

	pop     edx
	pop     ecx
	pop     ebx

	ret

segment readable writeable

konsola		db	"/dev/console", 0

struc	timespec
 {
	.tv_sec		rd 1
	.tv_nsec	rd 1
 }

t1 timespec
t2 timespec

Mam nadzieję, że podałem wystarczająco informacji, abyście samodzielnie zaczęli programować głośniczek. Jeśli mi się nie udało, to zawsze możecie skorzystać z gotowej procedury z mojej biblioteki.

Jeśli program nie powoduje wydawania żadnych dźwięków, może trzeba wkompilować obsługę głośniczka do jądra (lub załadować odpowiedni moduł). Czasem mogą być potrzebne uprawnienia administratora.

To już koniec. Miłej zabawy!